# MATH 2.   Double Integrals in Polar Coordinates
#                               23 October 1996.
# 
# 
# We consider finding some volumes of solids using
# polar coordinates.
# 
# First find the volume of half of the ellipsoid
#   x^2 + y^2 + 4 z^2 <= 4
# We look over z>=0. The upper surface is given by
#   z = sqrt(4-x^2-y^2) / 2
# 
# In polar coordinates:  z = sqrt(4-r^2) / 2.
#      so r = sqrt(4-4z^2)
# 
# Plot the function using cyclindrical coordinates.
# This requires expressing r in terms of theta and z:
> with(plots):
--------------------------------------------------------------------------------
> cylinderplot(sqrt(4-4*z^2),theta=0..2*Pi,z=0..1,color=red);
# 
# Express the upper surface as a function of r and theta:
# 
> f := sqrt(4-r^2) / 2;

                                             2 1/2
                              f := 1/2 (4 - r )
--------------------------------------------------------------------------------
# Integrate first with respect to r.
# Note that we need to multiply f by r.
> INTr := int(r*f,r=0..2);

                                   INTr := 4/3
--------------------------------------------------------------------------------
# Now integrate with respect to theta to get the final answer:
> integral := int(INTr,theta=0..2*Pi);

                               integral := 8/3 Pi
--------------------------------------------------------------------------------
# SECOND VOLUME:
# We now look at the surface below the curve z=xy
# and in the petal within the first orthant given by
#     r <= sin(2 theta).
# Express the surface in polar coordinates:
> g := r^2 * cos(theta) * sin(theta);

                                2
                          g := r  cos(theta) sin(theta)
--------------------------------------------------------------------------------
# We integrate first with respect to r.
# We have to multiply g by r.
# r is restricted to a range depending on theta.
> int1 := int(r*g, r=0..sin(2*theta));

                                         4
                 int1 := 1/4 sin(2 theta)  cos(theta) sin(theta)
--------------------------------------------------------------------------------
> volume := int(int1, theta=0..Pi/2);

                                 volume := 1/15
--------------------------------------------------------------------------------
# Plot the surface.
#   "petal" is the cylinder above the region  r <= sin(2theta).
> petal:=cylinderplot(sin(2*theta),theta=0..Pi/2,z=0..1,color=yellow):
--------------------------------------------------------------------------------
#   "surface is the surface itself.
> surface := plot3d(x*y,x=0..1,y=0..1,color=red):
--------------------------------------------------------------------------------
# Plot the cylinder and the surface on the same picture.
# "volume" is the volume under the surface that is within
# the cylinder.
> display({petal,surface});
--------------------------------------------------------------------------------
>